SUBROUTINE CR2DET(GAMMA,GAMMA2,SCF,AMBIENT,TIME,BAD)
C
C OUTPUT DETAIL DATA FROM CR-2 EDR PROCESSING.
C
C ORIGINAL SOURCE - SBK 04/04/96
C
      CHARACTER DATAID*4
      INTEGER*2 TIME(6),CR2TIME(6),DELTA(6),
     &          DATATYPE(2),WORD30(2),WORD32(2)
      REAL*4 HDR(32),TIMEPD
      REAL*4 GAMMA(3,400),GAMMA2(3,200),SCF(3,400),AMBIENT(3,400),
     &       PRIDAT(3,400),SECDAT(3,200),SCFDAT(3,400),AMBDAT(3,400)
      REAL*4 SPV(6),RANGE,ANG(2),PL(3),
     &       HG(3,400),MTB(3,3),MTB5(3,3),MHG(3,3)
      REAL*8 TD,TN,TP
C
      DATA DELTA/5*0,120/
C
      INCLUDE 'UNPACK.INC'
C
      EQUIVALENCE (SUMOUT(1),HDR(1)),    (DETOUT(1),HDR(1)),
     &            (HDR(1),DATAID),       
     &            (HDR(12),TIMEPD),      (HDR(17),DATATYPE(1)), 
     &            (HDR(30),WORD30(1)),   (HDR(32),WORD32(1))
C
      RECWRITE = RECWRITE + 1 
C
      CR2TIME(1) = TIME(1)
      CR2TIME(2) = TIME(2)
      CR2TIME(3) = TIME(3)
      CR2TIME(4) = TIME(4)
      CR2TIME(5) = TIME(5)
      CR2TIME(6) = TIME(6)
C
      DATAID = 'LFM '
      TIMEPD = 48.0
      DATATYPE(1) = 1
      WORD32(1) = RECWRITE
C
      IF ( SYS2(4) ) THEN
       WORD30(1) = 400
       WORD30(2) = 200
       WORD32(2) = 1800
      ELSE IF ( SYS2(5) ) THEN
       WORD30(1) = 400
       WORD30(2) = 400
       WORD32(2) = 2400
      END IF
C
C REASSIGN DETAIL VALUES TO LOCAL VARIABLES
C
      DO I = 1,400
C
C SECONDARY MAG SAMPLE COUNTER (1-200)
C
       ISEC = (I-1)/2 + 1
C
       PRIDAT(1,I) = GAMMA(1,I)
       PRIDAT(2,I) = GAMMA(2,I)
       PRIDAT(3,I) = GAMMA(3,I)
C
C AVOID RENDUNDANT ASSIGNMENTS
C
       IF ( MOD(I-1,2).EQ.0 ) THEN
        SECDAT(1,ISEC) = GAMMA2(1,ISEC)
        SECDAT(2,ISEC) = GAMMA2(2,ISEC)
        SECDAT(3,ISEC) = GAMMA2(3,ISEC)
       END IF
C
       AMBDAT(1,I) = AMBIENT(1,I)
       AMBDAT(2,I) = AMBIENT(2,I)
       AMBDAT(3,I) = AMBIENT(3,I)
C
       SCFDAT(1,I) = SCF(1,I)
       SCFDAT(2,I) = SCF(2,I)
       SCFDAT(3,I) = SCF(3,I)
C       
      END DO
C
      IF ( SYS2(7) ) THEN
C
C GET SEDR DATA
C
       CALL GETSEDR(TIME,TD,TN,TP,SPV,RANGE,ANG,MTB,MTB5,MHG)
C
       IF ( SYS2(4) ) THEN
C
C ROTATE PRIMARY AND SECONDARY DATA INTO HG COORDINATES
C
        CALL ROTATE(HG,PRIDAT,MHG,400,BAD)
        DO II = 1,400
         PRIDAT(1,II) = HG(1,II)
         PRIDAT(2,II) = HG(2,II)
         PRIDAT(3,II) = HG(3,II)
        END DO
C
        CALL ROTATE(HG,SECDAT,MHG,200,BAD)
        DO II = 1,200
         SECDAT(1,II) = HG(1,II)
         SECDAT(2,II) = HG(2,II)
         SECDAT(3,II) = HG(3,II)
        END DO
C
       ELSE IF ( SYS2(5) ) THEN
C
C ROTATE AMBIENT AND SPACECRAFT FIELD DATA INTO HG COORDINATES
C
        CALL ROTATE(HG,AMBDAT,MHG,400,BAD)
        DO II = 1,400
         AMBDAT(1,II) = HG(1,II)
         AMBDAT(2,II) = HG(2,II)
         AMBDAT(3,II) = HG(3,II)
        END DO
C
        CALL ROTATE(HG,SCFDAT,MHG,400,BAD)
        DO II = 1,400
         SCFDAT(1,II) = HG(1,II)
         SCFDAT(2,II) = HG(2,II)
         SCFDAT(3,II) = HG(3,II)
        END DO
C
       END IF
C
      END IF
C
C WRITE 48 SECOND CR-2 RECORD 
C
      DO I = 1,400
C
C SECONDARY MAG SAMPLE COUNTER (1-200)
C
       ISEC = (I-1)/2 + 1
C
       IF ( SYS2(4) ) THEN
C
C OUTPUT PRIMARY FIELD X,Y,Z FOLLOWED BY SECONDARY FIELD X,Y,Z
C
        DETOUT(32+I) = PRIDAT(1,I)
        DETOUT(32+400+I) = PRIDAT(2,I)
        DETOUT(32+800+I) = PRIDAT(3,I)
C
C AVOID RENDUNDANT ASSIGNMENTS
C
        IF ( MOD(I-1,2).EQ.0 ) THEN
         DETOUT(32+1200+ISEC) = SECDAT(1,ISEC)
         DETOUT(32+1400+ISEC) = SECDAT(2,ISEC)
         DETOUT(32+1600+ISEC) = SECDAT(3,ISEC)
        END IF
C
        IF ( SYS2(6) ) THEN
         WRITE(84,800) CR2TIME,I,(PRIDAT(J,I),J=1,3),
     &                 I,(GAMMA(J,I),J=1,3)
         IF ( MOD(I-1,2).EQ.0 ) 
     &    WRITE(85,800) CR2TIME,ISEC,(SECDAT(J,ISEC),J=1,3),
     &                  ISEC,(GAMMA2(J,ISEC),J=1,3)
        END IF
C
       ELSE IF ( SYS2(5) ) THEN
C
C OUTPUT AMBIENT FIELD X,Y,Z FOLLOWED BY SPACECRAFT FIELD X,Y,Z
C
        DETOUT(32+I) = AMBDAT(1,I)
        DETOUT(32+400+I) = AMBDAT(2,I)
        DETOUT(32+800+I) = AMBDAT(3,I)
C
        DETOUT(32+1200+I) = SCFDAT(1,I)
        DETOUT(32+1600+I) = SCFDAT(2,I)
        DETOUT(32+2000+I) = SCFDAT(3,I)
C
        IF ( SYS2(6) ) THEN 
         WRITE(84,800) CR2TIME,I,(AMBDAT(J,I),J=1,3),
     &                 I,(AMBIENT(J,I),J=1,3)
         WRITE(85,800) CR2TIME,I,(SCFDAT(J,I),J=1,3),
     &                 I,(SCF(J,I),J=1,3)
        END IF
C
       END IF
C
       CALL INC_TIME(CR2TIME,DELTA)
C
      END DO
C
C OUTPUT 48 SECOND RECORD W/HEADER BLOCK
C
      IF ( SYS2(4).AND..NOT.SYS2(5) ) THEN
       LEN = 1800 + 32  
      ELSE IF ( SYS2(5).AND..NOT.SYS2(4) ) THEN
       LEN = 2400 + 32
      ELSE
       WRITE(68,*)
       WRITE(68,*) 
     &  '*CR2DET*  ENTRY INTO DETAIL OUTPUT ROUTINE WITH BAD FLAGS'
       LEN = 0
       STOP
      END IF
      WRITE(66) (DETOUT(I),I=1,LEN)
C
      RETURN
  800 FORMAT(1X,I2,1X,I3.3,3(1X,I2.2),1X,I3.3,2(1X,I4,3(1X,F9.3)))
      END