;+
;
; :Description:
;   Generate summary plot of B field MMS data.
;   All four S/C on each panel, each with separate traces.
;	Specifically load Mag L2 data.
;
;   Panel Layout:
;
;     |--------------Bx-----------------|
;
;     |--------------By-----------------|
;
;     |--------------Bz-----------------|
;
;     |-------------Btot----------------|
;
;     MMS1 GSM 
;
;     U.T.
;
;
; :Keywords:
;   trange : optional, type=array
;     default=['2015-09-30/11:30:00','2015-09-30/12:30:00']
;
;   outfilepath : optional, type=string
;     Define the output file path, default='./'
;   magsamescale : optional
;     Fix the same scale for Bx, By, Bz, 0<Btot<2Bmax, default='no'
;
;     /magsamescale
;
;   ptstoavg: optional
;     Set number of points to average to reduce file size, default=1
;
; :Requires:
;	Unix/linux/Mac OS X only.  Not built for Windows.
;
;   Tested using: spdsw_r20463_2016-03-15
;   
; :Author:
;	Steven Martin
;
; :Version:
;   1.0
;-
pro mms_plot_fgm_example, trange=trange, outfilepath=outfilepath, $
	magsamescale=magsamescale, ptstoavg=ptstoavg


; Process (optional) keywords
;
; Default values
trange_d=['2015-09-30/11:30:00','2015-09-30/12:30:00']
outfilepath_d='./'
magsamescale_d='yes'
ptstoavg_d=1

; Input values
if keyword_set(trange) then trange=trange else trange=trange_d
if keyword_set(outfilepath) then outfilepath=outfilepath else outfilepath=outfilepath_d
if keyword_set(magsamescale) then magsamescale=magsamescale_d else magsamescale='no'
if keyword_set(ptstoavg) then ptstoavg=ptstoavg else ptstoavg=ptstoavg_d
if (strmid(outfilepath, 0,/reverse_offset) NE '/') then outfilepath += '/'

print, trange, outfilepath, magsamescale, ptstoavg,  $ 
	format='("    trange= ", 2(a-20),/,"outfilepath= ",a-80,/,"magsamescale= ",a-3,/,"ptstoavg= ",i-5,/,/)'

script='mms_summary_fgm_example.pro'
version='v1'
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
; Set timespan, level
timespan, trange

level = 'L2'
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;

;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
; Construct title date and filename 
startstr=STRSPLIT(trange[0],'/',/extract)
endstr=STRSPLIT(trange[1],'/',/extract)
startdatestr=startstr[0]
enddatestr=endstr[0]
startHHMMSSstr=STRSPLIT(startstr[1],':',/extract)
endHHMMSSstr=STRSPLIT(endstr[1],':',/extract)

timespan_filename_append=startdatestr+'_'+startHHMMSSstr[0]+'_'+startHHMMSSstr[1]+ $
	'_'+startHHMMSSstr[2]+'-to-'+enddatestr+'_'+endHHMMSSstr[0]+'_'+endHHMMSSstr[1]+ $
	'_'+endHHMMSSstr[2]
	
outfile=outfilepath+'mms_summary_fgm_allsc_'+version+'_'+level+'_'+timespan_filename_append+'.ps'

print, timespan_filename_append
print, outfile

startdate=startstr[0]
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;

;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
; Plot title
plottitle='!3MMS Summary Plot - '+startdate + '!c!cMagnetometer Instrument ('+level+', '+strtrim(string(ptstoavg),2)+' pt avg) '
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;

;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
; Load Instrument Data MAG
; Use specifically L2
level_fgm='l2'
mms_load_fgm, probes=['1','2','3','4'], level=level_fgm, $
	 varformat='*fgm_b_gsm_srvy_l2*', data_rate='srvy',/spdf

sc_id='mms1'  ; Use for base panel
	get_data,sc_id+'_fgm_b_gsm_srvy_l2',data=d_mms1
	store_data,sc_id+'_fgm_srvy_mag_bx',data={x:d_mms1.x,y:d_mms1.y(*,0)}
	store_data,sc_id+'_fgm_srvy_mag_by',data={x:d_mms1.x,y:d_mms1.y(*,1)}
	store_data,sc_id+'_fgm_srvy_mag_bz',data={x:d_mms1.x,y:d_mms1.y(*,2)}
	store_data,sc_id+'_fgm_srvy_mag_btot',data={x:d_mms1.x,y:d_mms1.y(*,3)}
sc_id='mms2'
	get_data,sc_id+'_fgm_b_gsm_srvy_l2',data=d_mms2
	tbmms2=d_mms2.x
	dbxmms2=d_mms2.y(*,0)
	dbymms2=d_mms2.y(*,1)
	dbzmms2=d_mms2.y(*,2)
	dbtotmms2=d_mms2.y(*,3)
sc_id='mms3'
	get_data,sc_id+'_fgm_b_gsm_srvy_l2',data=d_mms3
	tbmms3=d_mms3.x
	dbxmms3=d_mms3.y(*,0)
	dbymms3=d_mms3.y(*,1)
	dbzmms3=d_mms3.y(*,2)
	dbtotmms3=d_mms3.y(*,3)
sc_id='mms4'
	get_data,sc_id+'_fgm_b_gsm_srvy_l2',data=d_mms4
	tbmms4=d_mms4.x
	dbxmms4=d_mms4.y(*,0)
	dbymms4=d_mms4.y(*,1)
	dbzmms4=d_mms4.y(*,2)
	dbtotmms4=d_mms4.y(*,3)	
	
; Determine y-axis limits if magsamescale='yes'
if (magsamescale EQ 'yes') then begin
	tindex=where((d_mms1.x ge time_double(trange[0])) and (d_mms1.x le time_double(trange[1])))
	ymag_min=min([d_mms1.y[tindex,*],d_mms2.y[tindex,*],d_mms3.y[tindex,*],d_mms4.y[tindex,*]])
	ymag_max=max([d_mms1.y[tindex,*],d_mms2.y[tindex,*],d_mms3.y[tindex,*],d_mms4.y[tindex,*]])

	print, ymag_min, ymag_max, format='(/,"ymag_min= ",e12.5,2x,"ymag_max= ", e12.5,/)'
	print, time_string(min(d_mms1.x[tindex])), time_string(max(d_mms1.x[tindex])), format='("min t= ",a-20,2x,"max t= ", a-20)'
endif
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;

;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
; Load ephemeris data, Use MMS1 for position information
mms_load_mec, probe='1', varformat='*mec_r_gsm*'

sc_id='mms1'
get_data, sc_id+'_mec_r_gsm', data=mms_ephem

ephem_times = mms_ephem.x

Re = 6378.137
mms_x = mms_ephem.y(*,0)/Re
mms_y = mms_ephem.y(*,1)/Re
mms_z = mms_ephem.y(*,2)/Re
mms_r = sqrt(mms_x^2 + mms_y^2 + mms_z^2)

store_data, sc_id+'_x', data = {x:ephem_times, y:mms_x}
options, sc_id+'_x', 'ytitle', sc_id+' X'
store_data, sc_id+'_y', data = {x:ephem_times, y:mms_y}
options, sc_id+'_y', 'ytitle', sc_id+' Y'
store_data, sc_id+'_z', data = {x:ephem_times, y:mms_z}
options, sc_id+'_z', 'ytitle', sc_id+' Z'
store_data, sc_id+'_r', data = {x:ephem_times, y:mms_r}
options, sc_id+'_r', 'ytitle', sc_id+' R'
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;

;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
; Plot Stacked panel plots
;
tplot_options,'ygap',1.3 ; set vertical gap size between panels 
                         ;(the default gap is often too large with multi panels)
; reset ticks to point outward
lengthxticks=-0.03
lengthyticks=-0.008
;
;;;;;;;;;;;;;;;;;;;;;;;;;;
; DFG options

; Set fixed y-axis scale if magsamescale='yes'
if (magsamescale EQ 'yes') then begin
	options, 'mms1_fgm_srvy_mag_btot', ytitle='MAG!csrvy!c!c!cB!DTOT!N (GSM) [nT]', yrange=[0, 2*ymag_max], ystyle=17, constant=0, labflag=-1, nsum=ptstoavg
	options, 'mms1_fgm_srvy_mag_bx', ytitle='MAG!csrvy!c!cB!DX!N (GSM) [nT]', yrange=[ymag_min, ymag_max], ystyle=17, constant=0, labflag=-1, nsum=ptstoavg
	options, 'mms1_fgm_srvy_mag_by', ytitle='MAG!csrvy!c!cB!DY!N (GSM) [nT]', yrange=[ymag_min, ymag_max], ystyle=17, constant=0, labflag=-1, nsum=ptstoavg
	options, 'mms1_fgm_srvy_mag_bz', ytitle='MAG!csrvy!c!cB!DZ!N (GSM) [nT]', yrange=[ymag_min, ymag_max], ystyle=17, constant=0, labflag=-1, nsum=ptstoavg
endif else begin
	options, 'mms1_fgm_srvy_mag_btot', ytitle='MAG!csrvy!c!c!cB!DTOT!N (GSM) [nT]', labflag=-1, ystyle=17, constant=0, nsum=ptstoavg
	options, 'mms1_fgm_srvy_mag_bx', ytitle='MAG!csrvy!c!cB!DX!N (GSM) [nT]', ystyle=17, labflag=-1, constant=0, nsum=ptstoavg
	options, 'mms1_fgm_srvy_mag_by', ytitle='MAG!csrvy!c!cB!DY!N (GSM) [nT]', ystyle=17, labflag=-1, constant=0, nsum=ptstoavg
	options, 'mms1_fgm_srvy_mag_bz', ytitle='MAG!csrvy!c!cB!DZ!N (GSM) [nT]', ystyle=17, labflag=-1, constant=0, nsum=ptstoavg
endelse

name_fgm=['mms1_fgm_srvy_mag_bx','mms1_fgm_srvy_mag_by', $
	'mms1_fgm_srvy_mag_bz','mms1_fgm_srvy_mag_btot']

options,name_fgm,xticklen=lengthxticks,yticklen=lengthyticks
;;;;;;;;;;;;;;;;;;;;;;;;;;

;;;;;;;;;;;;;;;;;;;;;;;;;;
; Open Plot
; (postscript file)

; Access to plot window characteristics
print, 'Now plotting...'
@tplot_com

time_stamp, /off  ; Turn off annoying right hand time stamp on lowest panel
!p.charsize=0.6
!x.charsize=1.0
!p.font=-1

popen, outfile, /land

;;;;;;;;;;;;;;;;;;;;;;;;;;
; Plot base panels
; All with MMS1 - black
tplot,[name_fgm], var_label=[sc_id+'_z',sc_id+'_y',sc_id+'_x'], title=plottitle

help, tplot_vars
print, 'tplot_vars.settings.x.window:'
print, tplot_vars.settings.x.window
print, 'tplot_vars.settings.y.window:'
print, tplot_vars.settings.y.window
xpos=tplot_vars.settings.x.window
ypos=tplot_vars.settings.y.window

; Grab arrays with lower and upper y panel ranges used in tplot
; ylow[0]=panel 1, ylow[1]=panel 2, etc...
ylow=tplot_vars.settings.y.crange[0]
yup=tplot_vars.settings.y.crange[1]
xlow=tplot_vars.settings.x.crange[0]
xup=tplot_vars.settings.x.crange[1]
;;;;;;;;;;;;;;;;;;;;;;;;;;
; Overplot DFG
; Panel 1: Bx
; MMS2- Red
; MMS3- Green
; MMS4- Blue
!p.position=[xpos(0),ypos(0,0),xpos(1),ypos(1,0)]
plot, tbmms2, dbxmms2, xrange=time_double(trange), yrange=[ylow[0],yup[0]], xstyle=21, ystyle=21, line=0, nsum=ptstoavg, color=250, /noerase
plot, tbmms3, dbxmms3, xrange=time_double(trange), yrange=[ylow[0],yup[0]], xstyle=21, ystyle=21, line=0, nsum=ptstoavg, color=150, /noerase
plot, tbmms4, dbxmms4, xrange=time_double(trange), yrange=[ylow[0],yup[0]], xstyle=21, ystyle=21, line=0, nsum=ptstoavg, color=50, /noerase

;;;;;;;;;;;;;;;;;;;;;;;;;;
; Panel 2: By
!p.position=[xpos(0),ypos(0,1),xpos(1),ypos(1,1)]
plot, tbmms2, dbymms2, xrange=time_double(trange), yrange=[ylow[1],yup[1]], xstyle=21, ystyle=21, line=0, nsum=ptstoavg, color=250, /noerase
plot, tbmms3, dbymms3, xrange=time_double(trange), yrange=[ylow[1],yup[1]], xstyle=21, ystyle=21, line=0, nsum=ptstoavg, color=150, /noerase
plot, tbmms4, dbymms4, xrange=time_double(trange), yrange=[ylow[1],yup[1]], xstyle=21, ystyle=21, line=0, nsum=ptstoavg, color=50, /noerase

;;;;;;;;;;;;;;;;;;;;;;;;;;
; Panel 3: Bz
!p.position=[xpos(0),ypos(0,2),xpos(1),ypos(1,2)]
plot, tbmms2, dbzmms2, xrange=time_double(trange), yrange=[ylow[2],yup[2]], xstyle=21, ystyle=21, line=0, nsum=ptstoavg, color=250, /noerase
plot, tbmms3, dbzmms3, xrange=time_double(trange), yrange=[ylow[2],yup[2]], xstyle=21, ystyle=21, line=0, nsum=ptstoavg, color=150, /noerase
plot, tbmms4, dbzmms4, xrange=time_double(trange), yrange=[ylow[2],yup[2]], xstyle=21, ystyle=21, line=0, nsum=ptstoavg, color=50, /noerase

;;;;;;;;;;;;;;;;;;;;;;;;;;
; Panel 4: Btot
!p.position=[xpos(0),ypos(0,3),xpos(1),ypos(1,3)]
plot, tbmms2, dbtotmms2, xrange=time_double(trange),yrange=[ylow[3],yup[3]], xstyle=21, ystyle=21, line=0, nsum=ptstoavg, color=250, /noerase
plot, tbmms3, dbtotmms3, xrange=time_double(trange),yrange=[ylow[3],yup[3]], xstyle=21, ystyle=21, line=0, nsum=ptstoavg, color=150, /noerase
plot, tbmms4, dbtotmms4, xrange=time_double(trange),yrange=[ylow[3],yup[3]], xstyle=21, ystyle=21, line=0, nsum=ptstoavg, color=50, /noerase


;;;;;;;;;;;;;;;;;;;;;;;;;;
; Metadata on bottom of plot
create_date=systime()
xyouts, 1000.0, -400.0,'!8Date Created: '+create_date,size=0.5, /device
xyouts, 1000.0, -600.0, '!8file: '+outfile, size=0.5, /device
;;;;;;;;;;;;;;;;;;;;;;;;;;

;;;;;;;;;;;;;;;;;;;;;;;;;;	
; Key at bottom
xpos=19000.0
ypos=-200.0
dx=900.0
xyouts, xpos, ypos,'!5MMS1 ',size=0.75, /device
xyouts, xpos+dx, ypos, '!5MMS2 ', size=0.75, color=250, /device
xyouts, xpos+2.0*dx, ypos, '!5MMS3 ', size=0.75, color=150, /device
xyouts, xpos+3.0*dx, ypos, '!5MMS4 ', size=0.75, color=50, /device
;
;;;;;;;;;;;;;;;;;;;;;;;;;;	
pclose

;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
end