; ==== ISUAL Flight Software -- Univ of California, Berkeley, SSL ====
; PVCFDPU - generate PVCFs from Packets - DPU version
;   (this version does not use DCM)
;
; Revision History:
;  18-Dec-2002 - SPG - ISUAL Flight Software rev 7.3
;    First Official Release
;  26-July-2004
;    Bring up-to-date with PVCFDCM
;  26-Mar-2003 - SPG - FSW rev 7.7
;    PVCF_FLUSH writes dummy packet with PVCF_DPU, not PVCF_MM
;  6-Aug-2003
;    fixed PVCF_FLUSH to not write last PVCF
;    from partly undefined MM
; 13-Oct-2003 if MM off, pretend SC buffers are full
; (which prevents writing any more PVCFs)
; 16-Oct-2003
; implement GBL_PVSTART
; 21-Oct-2003 - eliminate "P" debug output
; 30-Oct-03 - release ILK if SC fault

dummy_packet
        db 0,0,0,0
        ds 2

PVCF_FLUSH:
; force a flush of the current PVCF by sending
; a dummy packet which begins with zero
; (marking the end of a PVCF stream for the
; ground software) and a length of 1105
;
; do nothing if PVCF_START hasn't been called
        lda GBL_PVSTART
        cpi 0
        rz 

        lxi h,1105
        mov a,h
        sta dummy_packet+4
        mov a,l
        sta dummy_packet+5
        lxi h,dummy_packet ; (header)
; ***6-Aug-2003 
        lxi d,GBL_PP_MMSC1  ; (MM addr of data)
        call PVCF_MM 
        ret

        include pvcf.i
        include ioports.i
        include util.i
        include gbl.i
        include mm.i
        include debug.i

; Functions to generate PVCFs from Packets - DPU version

;mm_fetch     equ GBL_PVCF_PROM 
;mm_store     equ GBL_PVCF_PROM+16

G          equ GBL_PVCF_PROM+32
vcfc         equ G+0  ; ds 1    ; Virtual Channel Frame Count
p_pvcf       equ G+1  ; ds 2    ; pointer into PVCF
mm_addr      equ G+3  ; ds 4    ; MM addr of current PVCF
; pointer to count of PVCFs stored
pCount       equ G+7  ; ds 2
; location and size of spacecraft buffers
current_store_buffer equ G+9 ; ds 1  ; 1 or 2
source_count equ G+10 ; ds 2
dest_count   equ G+12 ; ds 2
chktlr       equ G+14 ; ds 1
;        db 0AAh
p_source     equ G+16 ; ds 2
checksum     equ G+18 ; ds 1

PVCF_INIT:
        mvi a,0FFh
        sta GBL_DCM_STATUS   ; not using the DCM
        mvi a,0
        sta GBL_PVCF_ILK ; not using interlock either
        sta vcfc         ; Virtual Frame counter =0
        mvi a,0AAh
        sta chktlr+1
        ret

; GBL.I allocates 60 bytes to "PVCF_PROM" workarea

; GBL_PVCF is a work area for building a PVCF
;  includes one byte slop for storing final 0
pvcf    equ GBL_BPVCF

; high 5 bits of 2nd byte of PVCF header
; 0 - sec header flag
; 0 - synchro
; 0 - packet order
; 11- segment length code
hdrbits equ 18h


; size of PVCF = 1108 bytes, or 277 32-bit words (115 hex)
; as a 4-byte number
C1108           db 0,0,01h,15h 

PVCF_START:
        push psw
        push b
        push d
        push h

; setup first PVCF
        call new_pvcf   
; set pointer to 1st spacecraft buffer
        lxi h,GBL_PP_MMSC1
        lxi d,mm_addr
        mvi c,4
        call copy_bytes
; we are filling buffer 1
        mvi a,1
        sta current_store_buffer
; set SC buffers to empty
        mvi a,0
        sta GBL_SC_BUF1
        sta GBL_SC_BUF2
        lxi h,0
        shld GBL_SOH+71
        shld GBL_SOH+73
; set pointer to PVCF count
        lxi h,GBL_SOH+71
        shld pCount

        mvi a,1
        sta GBL_PVSTART  ; PVCF_START has now been called

        pop h
        pop d
        pop b
        pop psw
        ret



; Send packet from DPU memory
;  HL - address of Primary and Secondary headers
;  DE - address of data
PVCF_DPU:
        push psw
        push b
        push d
        push h

; if both SC buffers full, throw away data
        lda GBL_SC_BUF1
        cpi 1
        jnz okdpu
        lda GBL_SC_BUF2
        cpi 1
        jnz okdpu
scfault:
        lxi h,GBL_SOH+75   ; SC Fault
        inr M
        mvi a,1
        sta GBL_SOH+12  ; at least one fault happened
        jmp xit
okdpu:

        push d          ; >>save data pointer 
; copy primary header
        call copy_header_to_pvcf
; get data length
        lxi b,4
        dad b           ; point to last 2 bytes of pri hdr
        mov b,M
        inx h
        mov c,M
        push b          ; >>save length
        inx h

; clear checksum (accumulated by 'copy_to_pvcf')
        mvi a,0
        sta checksum    

; copy secondary header to PVCF
        lxi b,10
        call copy_to_pvcf

; get length of data to follow
        pop b           ; <<restore length
        lxi h,-11       ; deduct for 2ndry hdr and cksum
        dad b
; output data
        mov b,h
        mov c,l         ; BC = data length
        pop h           ; <<restore data pointer
        call copy_to_pvcf

; output checksum and trailer
outck:  lda checksum
        sta chktlr
        lxi h,chktlr
        lxi b,2
        call copy_to_pvcf
xit:    pop h
        pop d
        pop b
        pop psw
        ret


; Send Data Packet, getting data from Mass Memory
;  HL - points to Headers plus 
;   other Science Data Packet stuff (4 more bytes)
;  DE - points to MM address of data
PVCF_MM:
        push psw
        push b
        push d
        push h

; if both SC buffers full, throw away data
        lda GBL_SC_BUF1
        cpi 1
        jnz okmm
        lda GBL_SC_BUF2
        cpi 1
        jz scfault
okmm:
        push d          ; >>save MM address pointer
        push h          ; >>save pointer th headers plus

; copy primary header
        call copy_header_to_pvcf

; clear checksum (accumulated by 'copy_to_pvcf')
        mvi a,0
        sta checksum    

; copy secondary header and other stuff to PVCF
        lxi b,6         ; step past pri hdr
        dad b
        lxi b,14
        call copy_to_pvcf
 
; get number-of-valid-words from packet data
        pop h           ; <<restore pointer to headers plus
        lxi d,18
        dad d           ; point to "number of valid words"
        mov b,M         ; high order
        inx h
        mov c,M         ; low order
; Read number-of-valid-words 
; from MM, and output
        pop d           ; <<restore MM address pointer
        lxi h,GBL_4K
        call mm_fetch
        lxi b,4072      ; 1018*4
        call copy_to_pvcf

; output checksum and trailer
        jmp outck


PVCF_FLUSH:
; force a flush of the current PVCF by sending
; a dummy packet which begins with zero
; (marking the end of a PVCF stream for the
; ground software) and a length of 1105
;
; do nothing if PVCF_START hasn't been called
        lda GBL_PVSTART
        cpi 0
        rz 

        lxi h,1105
        mov a,h
        sta dummy_packet+4
        mov a,l
        sta dummy_packet+5
        lxi h,dummy_packet ; (header)
; ***6-Aug-2003 
        lxi d,GBL_PP_MMSC1  ; (MM addr of data)
        call PVCF_MM 
        ret

; Build a new PVCF
new_pvcf:
        push psw
        push h
;  store virtual channel frame count as 1st byte of PVCF
        lda vcfc
        sta pvcf
        inr a           ; increment
        sta vcfc
; store bytes 1 and 2 with all 1's in first header pointer 
        mvi a,hdrbits+07h
        sta pvcf+1
        mvi a,0FFh
        sta pvcf+2
; initialize pointer to data part of PVCF
        lxi h,pvcf+3
        shld p_pvcf
; put in a zero to mark end of data
        mvi M,0
        pop h
        pop psw
        ret

copy_header_to_pvcf:
        push psw
        push b
        push d
        push h

        push h          ; save header pointer
; define first header pointer, if needed
        lda pvcf+1
        ani 07h             ; bits are on if undefined
        cpi 07h
        jnz defined
; store new first header pointer
        lhld p_pvcf
        lxi d,pvcf+3
; offset into data = p_pvcf - (pvcf+3)
        call SUB16      
        mvi a,hdrbits     ; bits in PVCF header
        ora h             ; high 3 bits of offset
        sta pvcf+1
        mov a,l           ; low 8 bits of offset
        sta pvcf+2
defined:
        pop h           ; restore header pointer
        lxi b,6         ; pri hdr is 6 bytes
        call copy_to_pvcf
        pop h
        pop d
        pop b
        pop psw
        ret


COPY_TO_PVCF:                                    
; Copy a byte array into one or more PVCFs
; HL - points to source byte array
; BC - byte count
        push psw
        push b
        push d
        push h
        shld p_source

; number of bytes available in PVCF
        lhld p_pvcf
        xchg
        lxi h,pvcf+1108
        call sub16 
        xchg    ; DE = available destination count
; p_source - source in packet
; p_pvcf   - destination in PVCF
; BC - source count
; DE - destination count
cploop:
        lhld p_source           ; get source pointer

; accumulate checksum 
        lda checksum            
        xra M
        sta checksum

        mov a,M                 ; fetch source byte
        inx h                   ; increment
        shld p_source
        lhld p_pvcf             ; get destination pointer
        mov M,a                 ; store byte
        inx h                   ; increment destination
        shld p_pvcf
        dcx b                   ; Decrement source count
        dcx d                   ; Decrement destination count
        mov a,d
        ora e
        jnz cpmore
; PVCF is full; store it in Mass Memory.
; Preserve source and destination counts
        mov h,b
        mov l,c
        shld source_count
; store PVCF in MM
        call STORE_PVCF
; advance MM address
        lxi h,c1108+3   ; low byte of 1108/4 in 4-byte form
; 4-byte add
        lxi d,MM_addr+3
        ldax d  ; byte 3
        add M             
        stax d
        dcx d
        dcx h
        ldax d  ; byte 2
        adc M           ; add with carry 
        stax d
        dcx d
        dcx h
        ldax d  ; byte 1
        adc M           ; add with carry 
        stax d
        dcx d
        dcx h
        ldax d  ; byte 0
        adc M           ; add with carry 
        stax d

; increment count of PVCFs stored
        lhld pCount
        call incbig

; Was this the last PVCF into the current buffer?
        lxi d,GBL_PP_MAXNPVCFS+2        ; (look at low 16 bits)
        ldax d
        cmp M
        jnz notlast
        inx d
        ldax d
        inx h
        cmp M
        jnz notlast

; Last PVCF was stored.
; Change store-address to other buffer
        lda current_store_buffer
        cpi 2
        jz was2

; buffer 1 is now full
        mvi a,1
        sta GBL_SC_BUF1
; switch storing to buffer 2
        mvi a,2
        sta current_store_buffer
; set MM address to SC buffer 2
        lxi h,GBL_PP_MMSC2
        lxi d,MM_addr
        mvi c,4
        call copy_bytes
; set pointer to the count in SOH
        lxi h,GBL_SOH+73        ; IDH_N_SC2
        shld pCount
        jmp notlast

; buffer 2 is now full
was2:   
        mvi a,1
        sta GBL_SC_BUF2
; switch storing to buffer 1
        mvi a,1
        sta current_store_buffer
; set MM address to SC buffer 1
        lxi h,GBL_PP_MMSC1
        lxi d,MM_addr
        mvi c,4
        call copy_bytes
; set pointer to the count in SOH
        lxi h,GBL_SOH+71  ; IDH_N_SC1
        shld pCount

notlast:
; set up a new PVCF
        call new_pvcf
        lxi d,1105      ; = destination count for an empty PVCF
        lhld source_count
        mov b,h
        mov c,l
cpmore:
; source count is in BC
; destination count is in DE
        mov a,b
        ora c           ; source count is zero?
        jnz cploop      ;  not yet

; copy complete
; Store a zero to mark a non-packet, in case this turns
; out to be the last PVCF
; (GBL PVCF allocation has a spare byte after it)
        lhld p_pvcf
        mvi M,0
; (let the zero get over-written by 
; the next copy into the PVCF)
        pop h
        pop d
        pop b
        pop psw
        ret

STORE_PVCF:
        lxi h,pvcf  
        lxi d,mm_addr
        lxi b,1108/4
        call mm_store
        ret