%{

#define YY_NO_INPUT

#include <stdlib.h>
#include <string.h>
#include "pidf.h"          /* for PIDF_GetFileName */
#include "symtab.h"
#include "pidf.y.tab.h"
int pidf_lineno = 1;
%}
%option nounput
%s COMMENT
%%

\n	{ pidf_lineno++; }
\$.*$                    ;   /* ignore comments */
<INITIAL>[ \t]+          ;   /* ignore whitespace */ 

<INITIAL>-?(([0-9]*\.[0-9]+)([eE][-+]?[0-9]+)?) |
<INITIAL>-?[0-9]+[eE][-+]?[0-9]+  { 
        yylval.pval = malloc (sizeof (float));
        *((float *) yylval.pval) = atof (yytext);
        return Y_FLOAT_NUM; 
    }

<INITIAL>-?[0-9]+        { 
        yylval.pval = malloc (sizeof (long));
        *((long *) yylval.pval) = atol (yytext);
        return Y_INT_NUM; 
    }

<INITIAL>0x[0-9A-Fa-f]+  {
                           yylval.pval = malloc (sizeof (long));
                           *((long *) yylval.pval) = strtol (yytext, (char **)NULL, 0);
                           return Y_INT_NUM;
                         }

<INITIAL>\"[^"\n]*["\n]  |
<INITIAL>\'[^'\n]*['\n]  { 
                           *(yytext + yyleng - 1) = '\0';    /* remove the last quote */
                           yylval.sval = strdup (yytext + 1); /* remove the first one */
                           return Y_QUOTED_STRING; 
                         }

\/\*.*\*\/      ;
\/\*            { BEGIN COMMENT; }

<COMMENT>.      ;
<COMMENT>\*\/   { BEGIN 0;}

<INITIAL>PIDF            |
<INITIAL>pidf            {  yylval.ival = Y_PIDF; return Y_PIDF; }

<INITIAL>STRUCT          |
<INITIAL>struct          {  yylval.ival = Y_STRUCT; return Y_STRUCT; }

<INITIAL>INT             |
<INITIAL>int             {  yylval.ival = Y_INT; return Y_INT; }

<INITIAL>FLOAT           |
<INITIAL>float           {  yylval.ival = Y_FLOAT; return Y_FLOAT; }

<INITIAL>CHAR            |
<INITIAL>char            {  yylval.ival = Y_CHAR; return Y_CHAR; }

<INITIAL>STRING          |
<INITIAL>string          {  yylval.ival = Y_STRING; return Y_STRING; }

<INITIAL>[a-zA-Z][a-zA-Z0-9_]*      { 
                                      yylval.sval = (void *) strdup (yytext); 
                                      return Y_NAME; 
                                    }

<INITIAL>\*              |
<INITIAL>.               {  return yytext [0]; }

%%

int yyerror (char *msg)
{

    static char ErrorPrinted;
    static char FileName [100];
    const char *PIDFFileName = PIDF_GetFileName ();

    if (strncmp (FileName, PIDFFileName, 100) != 0) ErrorPrinted = 0;
    if (!ErrorPrinted) {
        printf ("\nError in %s: Line %d : %s at '%s'\n", PIDFFileName, 
                pidf_lineno, msg, yytext);
        printf ("\nFix PIDF before continuing...\n\n");
        strcpy (FileName, PIDFFileName);
        ErrorPrinted = 1;
    }
    return -1;
}