SUBROUTINE FK5( T, PV )
C
C     GIVEN DYNAMIC TIME T IN JULIAN MILLENIA SINCE J2000, AND THE
C     MEAN ECLIPTIC POSITION AND VELOCITY (HELIOCENTRIC OR GEOCENTRIC,
C     REFERRED TO THE MEAN EQUINOX OF DATE) OF A PLANET, THIS ROUTINE
C     APPLIES THE CORRECTIONS, DL AND DB TO THE LONGITUDE AND LATITUDE
C     (AND DDLDT AND DDBDT TO THE VELOCITIES), WHICH ARE REQUIRED TO
C     TRANSFORM THE VSOP87 THEORY (JPL DYNAMIC EPHEMERIS) TO THE
C     STANDARD FK5 SYSTEM.  (ALGORITHM OF J. MEEUS, "ASTRONOMICAL
C     ALGORITHMS", WILLMANN-BELL, 1991, P. 207)
C
C     B. KNAPP, 1992-05-03, 1999-06-09, 2000-09-01
C
C
C     RCS DATA
C     
C     $Header$
C     
C     $Log$
C
C
C     IMPLICIT NONE
C
C     INPUT
      REAL*8 T
C
C     INPUT/OUTPUT
      REAL*8 PV(6)
C
C     CONSTANTS
      REAL*8 D2R, S2R
      PARAMETER (D2R=3.14159265358979324D0/180.D0, S2R=D2R/3600.D0)
      REAL*8 C1, C2, D1, D2, JM
      PARAMETER (C1 = -0.09033D0*S2R, C2 = 0.03916D0*S2R,
     &   D1 = -13.97D0*D2R, D2 = -0.031D0*D2R, JM=365250.D0)
C
C     LOCAL VARIABLES
      REAL*8 LP, DLP, CLP, SLP, CPS, CMS, TB 
C
      LP = PV(1) + T*( D1 + T*D2 )
      CLP = COS( LP )
      SLP = SIN( LP )
      CPS = CLP + SLP
      CMS = CLP - SLP
      DLP = PV(4) + (D1 + 2*T*D2)/JM
      TB = TAN( PV(2) )
      PV(1) = PV(1) + (C1 + C2*CPS*TB)
      PV(4) = PV(4) + C2*(DLP*CMS*TB + PV(5)*CPS/COS( PV(2) )**2)
      PV(2) = PV(2) + C2*CMS
      PV(5) = PV(5) - C2*CPS*DLP
C
      RETURN
      END