; ==============================================================================
;  run_3b.pro
;
;  Defines the run_3b procedure which serves as the driver
;  for the create_level_3b procedure.
;
;  Hard-coded variables:
;
;     version:  CIPS version number in mm.nn format (e.g., '05.20')
;     revision: CIPS revision number in nn format (e.g., '04')
;     season:   Season, in hemisphere_year format (e.g., 'north_2010')
;
;  Revision History:
;
;  <  Sep 2019    Jerry D. Lumpe       Initial Creation
;
;  16 Sep 2019    Paul E. Meade        Cleaned up, comments added
;
; ==============================================================================

pro run_3b
  ;  -------------
  ;  Check required IDL system variables
  ;  Note that this will fail if and only if the
  ;  environment variable 'aimsds' has not been set.
  ;  -------------
  DEFSYSV,'!DATA_PRODUCT_PATH', EXISTS=chk_exists
  if (chk_exists ne 1) then begin
    set_cips_production_vars
  endif
  set_debug_level, 0
  set_production_flag, flag=1

  ;  Start at the beginning of the AIM mission and continue to the present
  today = systime()
  time_regex = '.+ (20[0-2][0-9]).*'
  time_match = stregex(today, time_regex, /SUBEXPR, /EXTRACT)
  end_year = fix(time_match[1])
  for year = 2007, end_year do begin
    seasons = [ 'north', 'south' ]
    for i = 0, n_elements(seasons) - 1 do begin
      season = seasons[i] + '_' + strtrim(string(year), 2)
      print, season
      ;  Generate the 'version' and 'revision' elements of the file name:
      ; version should be something like '05.20'
      version = !VERSION_3
      if strlen(version) eq 4  then version='0'+version
      ; revision should be something like '01
      revision = !REVISION_3
      if strlen(revision) eq 1  then revision='0'+revision
      create_level_3b, season, version, revision, status
      if status eq 0  then begin
        print, get_routine_name() + 'unable to create L3B movie for ' + season
      endif
    endfor
  endfor

end