PRO CIPS_QUALITY_SELECT_EVENT, event
COMMON QUALITY_SELECT, return_val

CASE WIDGET_INFO(event.id, /UNAME) OF
   'SLIDER': WIDGET_CONTROL, event.id, GET_VALUE=return_val
   'DONEBTN': WIDGET_CONTROL, event.handler, /DESTROY
ENDCASE

END

FUNCTION CIPS_QUALITY_SELECT, topBase
COMMON QUALITY_SELECT, return_val

return_val=50
if n_elements(topBase) eq 0 then                                           $
   base = widget_base(TITLE='Select Quality', /COLUMN, /BASE_ALIGN_CENTER) $
else base = widget_base(TITLE='Select Quality', /BASE_ALIGN_CENTER,        $
                        /COLUMN, /MODAL, GROUP_LEADER=topBase)
label = widget_text(base, YSIZE=4, /ALIGN_CENTER, $
                    value=['A higher quality setting, combined',$
                           'with a slower framerate, will result',$
                           'in a larger file size, so please',$
                           'choose accordingly.'])
quality_slider = widget_slider(base, value=return_val, minimum=1, maximum=100, $
                 UNAME='SLIDER', xsize=(WIDGET_INFO(base, /GEOM, UNITS=0)).xsize)
done_btn = widget_button(base, value='  Done  ', UNAME='DONEBTN')

WIDGET_CONTROL, base, /REALIZE
XMANAGER, 'CIPS_QUALITY_SELECT', base

RETURN, return_val
END