;docformat='rst'
;+
;    Fill in orbit info table as needed to the end of the currently available TLEs
;     (all orbits which end before the epoch of the second-to-last TLE in the table)
;
; :Author:
;    Chris Jeppesen, Bill Barrett
;
;-
;+
;
; :Keywords:
;   last_orbit_info : in, optional, type=struct
;     The starting point for filling in the orbit table.
;   verbose : in, optional, type=boolean
;     Generate a substantial amount of log information.
;     
; :Examples:
;     update_orbit_info
;-
pro update_orbit_info, last_orbit_info=last_orbit_info, verbose=verbose

  tle_end_time=get_tle_end(verbose=verbose)
  if keyword_set(verbose) then print, $
    get_routine_name() + "  Updating orbit info table to "+usec2vms(tle_end_time)

  if ~keyword_set(last_orbit_info) then last_orbit_info= get_last_orbit_info()

  if keyword_set(verbose) then print, $
    get_routine_name() + "  Orbit table already has orbits up to orbit #"+ $
    string(last_orbit_info.orbit_Number,format='(%"%d")')+", ending at "+ $
    usec2vms(last_orbit_info.stop_Time)
  if last_orbit_info.stop_Time gt tle_end_time then begin
      if keyword_set(verbose) then print, get_routine_name() + "  Orbit table is already up to date"
    return
  end
  
  orbits= generate_orbit_info(last_orbit_info.stop_Time, $
    last_orbit_info.orbit_Number+1, tle_end_time, verbose=verbose)
  write_orbit_info, orbits, verbose=verbose
end