; docformat = 'rst'
;+
;Given dynamical time T in Julian millenia since J2000, returns
;the mean obliquity of the ecliptic (neglecting nutation), in
;radians.  (algorithm of J. Laskar, Astronomy and Astrophysics
;157 (1986) P. 68, as presented by Jean Meeus, "Astronomical
;Algorithms", Wilmann-Bell, 1991.)
;
;CAUTION: THE ABSOLUTE VALUE OF T MUST BE LESS THAN OR EQUAL TO 10.
;
; :Author:
;   B. Knapp: 1992-05-02,
;             2000-09-01,
;   C. Jeppesen: 2009-10-08 (translated to IDL)
;   
; :Examples:
;   mean_obliquity = obliq(jul_time)
;-
;+
; :Params:
;   T : in, required, type=double or array of double
;     Dynamical time in Julian millenia since J2000.
;     
; :Returns:
;   Returns the mean obliquity of the ecliptic (neglecting nutation), in
;   radians.
;-
FUNCTION OBLIQ, T

      if ~real_numeric_type(T) then begin
        doc_library, 'obliq'
        return, -1
      endif

      U = double(T)/10.D0

      return, ( 23.43929111D0 + $
         U*( -4680.93D0 + $
         U*(    -1.55D0 + $
         U*(  1999.25D0 + $
         U*(   -51.38D0 + $
         U*(  -249.67D0 + $
         U*(   -39.05D0 + $
         U*(     7.12D0 + $
         U*(    27.87D0 + $
         U*(     5.79D0 + $
         U*      2.45D0 ) ) ) ) ) ) ) ) )/3600.D0 )*!const.dtor ;replaced D2R

END