      REAL*8 FUNCTION OBLIQ( T )
C
C     GIVEN DYNAMICAL TIME T IN JULIAN MILLENIA SINCE J2000, RETURNS
C     THE MEAN OBLIQUITY OF THE ECLIPTIC (NEGLECTING NUTATION), IN
C     RADIANS.  (ALGORITHM OF J. LASKAR, ASTRONOMY AND ASTROPHYSICS
C     157 (1986) P. 68, AS PRESENTED BY JEAN MEEUS, "ASTRONOMICAL
C     ALGORITHMS", WILLMANN-BELL, 1991.)
C
C     B. KNAPP, 1992-05-02, 2000-09-01
C
C
C     CAUTION: THE ABSOLUTE VALUE OF T MUST BE LESS THAN OR EQUAL TO 10.
C
C
C
C     RCS DATA
C     
C     $Header$
C     
C     $Log$
C
C
      IMPLICIT NONE
C
C     INPUT
      REAL*8 T
C
C     CONSTANT
      REAL*8 D2R
      PARAMETER (D2R = 3.14159265358979324D0/180.D0)
C
C     LOCAL
      REAL*8 U
C
      U = T/10.D0
C
      OBLIQ = ( 23.43929111D0 +
     &   U*( -4680.93D0 +
     &   U*(    -1.55D0 +
     &   U*(  1999.25D0 +
     &   U*(   -51.38D0 +
     &   U*(  -249.67D0 +
     &   U*(   -39.05D0 +
     &   U*(     7.12D0 +
     &   U*(    27.87D0 +
     &   U*(     5.79D0 +
     &   U*      2.45D0 ) ) ) ) ) ) ) ) )/3600.D0 )*D2R
C
      RETURN
      END
