      CHARACTER*3 FUNCTION CONSTELLATION(EPOCH,RA,DEC)
C
C     GIVEN AN JULIAN EPOCH (GREGORIAN YEAR AND FRACTION) AND THE RIGHT
C     ASCENSION (HOURS) AND DECLINATION (DEGREES) OF A POINT, RETURN
C     THE OFFICIAL THREE-LETTER IAU ABBREVIATION FOR THE NAME OF THE
C     CONSTELLATION IN WHICH THE POINT LIES.
C
C     B. KNAPP, 2001-04-26
C
C     REFERENCE: NANCY G. ROMAN, "IDENTIFICATION OF A CONSTELLATION
C     FROM A POSITION", PUBL. ASTRON. SOC. PACIFIC 99:695-699 (JULY
C     1987).
C
C
C     RCS DATA
C     
C     $Header$
C     
C     $Log$
C
C
      IMPLICIT NONE
C
C     INPUT:
      REAL*8 EPOCH
      REAL*4 RA, DEC
C
C     CONSTANTS
      REAL*8 J1875, PI, D2R, H2R
      PARAMETER (J1875=1875.D0)
      PARAMETER (PI=3.14159265358979324D0,D2R=PI/180.D0,H2R=PI/12.D0)
C
C     LOCAL VARIABLES
      REAL*8 DRA1875, DDEC1875
      REAL*4 RA1875, DEC1875
C
C     EXTERNALS
      CHARACTER*3 CONST1875
      EXTERNAL PRECESS, CONST1875
C
C     PRECESS CALLER'S RA, DEC TO 1875.0
      CALL PRECESS(EPOCH, J1875, DBLE(RA)*H2R, DBLE(DEC)*D2R,
     &   DRA1875, DDEC1875)
      RA1875 = REAL(DRA1875/H2R)
      DEC1875 = REAL(DDEC1875/D2R)
C
C     FIND THE CONSTELLATION
      CONSTELLATION = CONST1875(RA1875,DEC1875)
      RETURN
      END

