      SUBROUTINE ABERRAT(JDE, RA, DEC, DRA, DDEC)
C
C     FOR A GIVEN JULIAN EPHEMERIS DATE, COMPUTE THE EFFECT OF ANNUAL
C     ABERRATION ON THE POSITION OF A STAR WITH GIVEN RIGHT ASCENSION
C     AND DECLINATION.
C
C     B. KNAPP, 1993-06-18, 2000-11-15
C
C
C     RCS DATA
C     
C     $Header$
C     
C     $Log$
C
C
      IMPLICIT NONE
C
C     INPUT
      REAL*8 JDE, RA, DEC
C
C     OUTPUT
      REAL*8 DRA, DDEC
C
C     SPEED OF LIGHT (1E-8 AU/DAY)
      REAL*8 C
      PARAMETER (C=17314463350.D0)
C
C     LOCAL VARIABLES
      REAL*8 XYZ(3), SRA, CRA, SDEC, CDEC
C
C     EXTERNALS
      EXTERNAL ABERRAT_XYZ
C
C     GET THE RECTANGULAR COMPONENTS OF THE ANNUAL ABERRATION
      CALL ABERRAT_XYZ(JDE, XYZ)
C
C     COMPUTE THE ABERRATION IN RA AND DEC
      SRA = SIN(RA)
      CRA = COS(RA)
      SDEC = SIN(DEC)
      CDEC = COS(DEC)
      DRA = (XYZ(2)*CRA-XYZ(1)*SRA)/(C*CDEC)
      DDEC = -((XYZ(1)*CRA+XYZ(2)*SRA)*SDEC-XYZ(3)*CDEC)/C
C
      RETURN
      END
